# G376-386
Primer examen parcial
6 Nov 2020

kill(all);

Se define la sucesión del numerador, del siguiente modo:

a[n]:=sum(j^2,j,1,n), simpsum;

Y la sucesión del denominador:

b[n]:=k*n^3;

En principio. MAXIMA no es capaz de calcular el valor del límite de a[n]/b[n]:

limit(a[n]/b[n],n,inf);

Comprobamos que la serie es monótona (creciente):

assume(n>=1);

is(b[n+1] / b[n] > 1);

Y divergente (considerando que k es un valor real positivo):

assume(k>0);

limit(b[n],n,inf);

Siendo entonces aplicable el criterio de Stolz.

Se construye por lo tanto la expresión del Criterio de Stolz: a[n+1]-a[n])/(b[n+1]-b[n]

expr:(a[n+1]-a[n])/(b[n+1]-b[n]);

Es posible simplificar la expresión del numerador efectuando la diferencia a[n+1]-a[n], tal como se indica a continuación. Esto es necesario para que MAXIMA pueda resolver el límite:

numerador:sumcontract(intosum(num(expr)));

Y por lo tanto, aplicando Stolz:

L:limit(numerador/(b[n+1]-b[n]),n,inf);

Para que ambas sucesiones sean equivalentes, L debe valer 1:

solve(L=1,k);

Lo que nos da la solución, k=1/3

kill(all);

Primeramente se define la sucesión que genera la serie:

a[n]:=log(2*n/(2*n+1));

A continuación definimos la serie, que es una serie de términos positivos:

s[k]:=sum(a[n],n,1,k);

Se comprueba la condición necesaria de convergencia:

limit(a[n],n,inf);

Es cero, y por lo tanto no puede afirmarse que la serie sea divergente o convergente. Para aplicar el criterio de convergencia por paso al límite, nos apoyamos en otra serie cuyo carácter sea conocido. En este caso, la serie armónica:

b[n]:=1/n;

La serie armónica es divergente, como sabemos por sus propiedades.

A[k]:=sum(b[n],n,1,k);

La serie es divergente, y por lo tanto el cálculo de la suma infinita arroja error:

A[inf],simpsum;

Se calcula el límite en el infinito de a[n]/b[n]:

limit(a[n]/b[n],n,inf);

Y el resultado es un valor real finito diferente de cero. Por ello, podemos concluir que la serie a(n) es del mismo carácter que b(n), esto es, divergente. En este caso, la serie se va a -inf.

Lo comprobamos gráficamente representado gráficamente el valor de las primeras 100 sumas parciales:

valores_y:makelist(s[k],k,1,100)$

wxplot2d([discrete,makelist(x,x,1,100),valores_y],[style, points]);

Se aprecia que la serie es monótona creciente.

kill(all);

En este caso comprobaremos de forma visual el conjunto de definición de la función:

f(x):=log(x+3)/(x^2-1)^(1/4);

wxplot2d(f(x),[x,-4,10],[y,-3,3]);

Como se observa, D=(-3,-1)⋃(1,inf)

kill(all);

ec1:x^6+1;

Las raíces se obtienen de forma inmediata con 'solve'

sol:solve(ec1,x);

Alternativamente, podemos expresar la solución en forma exponencial:

sol,polarform;

Para representar las soluciones sobre el plano complejo, extraemos separadamente parte real e imaginaria de cada valor:

raices:map(rhs,sol);

parte_real:map(realpart, raices);

parte_imaginaria:map(imagpart, raices);

load(draw);

wxdraw2d(grid = true,
                proportional_axes=xy,
                color=red,    
                point_type=filled_circle,
                point_size=2,        
                yrange=[-1.5,1.5],    
                xrange=[-1.5,1.5],    
                points(parte_real,parte_imaginaria),
                color = black,
                parametric(t,0,t,-2.5,2.5),
                parametric(0,t,t,-2.5,2));

Los afijos del conjunto solución son los vértices de un hexágono regular sobre el plano complejo