# G1953 - Examen Parcial 3
15 Ene 2021

# Soluciones de los ejercicios

kill(all);

Se define la rama principal de la función. Se tiene en cuenta que f(0,0)=0

f(x,y):=(x^4+x^2*y-y^2)/(2*x^4+3*y^2);

Para estudiar la continuidad, calculamos primero los límites reiterados:

A lo largo del eje X:

limit(f(x,0),x,0);

Y en la dirección del eje Y:

limit(f(0,y),y,0);

Los limites reiterados no coinciden, y por lo tanto no existe el límite de la función en el origen. Por lo tanto, la función no es continua en el origen. Si será continua en todos los demas puntos de R2, ya que se trata de un cociente de polinomios cuyo denominador sólo se anula en el origen, no presentando por lo tanto ningún otro punto problemático.

Calculamos las derivadas parciales:

define(fx(x,y), diff(f(x,y),x,1))$factor(%);

define(fy(x,y), diff(f(x,y),y,1))$factor(%);

Las derivadas parciales están definidas en todo R2 salvo en el origen. Por lo tanto, la función es derivable en todo R2 salvo en (0,0). Lo comprobamos calculando las derivadas parciales en el origen partiendo de su definición:

x0:0$
y0:0$

limit((f(x0+h,y0)-0)/h,h,0);

limit((f(x0,y0+h)-0)/h,h,0);

Las derivadas son infinitas, y por lo tanto no existen.

Se puede afirmar que f es de clase C1 en R²-{0,0}, siendo diferenciable por lo tanto en todo su dominio salvo en (0,0)

Para calcular el plano tangente, aplicamos firectamente la fórmula, considerando el punto (a,b)=(1,1):

a:1$b:1$

f(a,b);

z(x,y):=fx(a,b)*(x-a)+fy(a,b)*(y-b)+f(a,b);

Esta es la representación gráfica del plano tangente:

draw3d(key="Superficie f(x,y)",
             explicit(f(x,y),x,-0.1,2,y,-0.1,2), 
             color="green",   
             key="Plano tangente",     
             explicit(z(x,y),x,0.5,1.5,y,0.5,1.5),
             point_type = filled_circle,    
             point_size=2,
             color="red",   
             key="Punto tangencia (1,1,f\(1,1\))",         
             points([[a,b,f(a,b)]]));

kill(all);

f(x,y):=x^2+y^2+x*y+3*y-5;

Se calculan las derivadas parciales:

fx:diff(f(x,y),x);

fy:diff(f(x,y),y);

Se resuelve el sistema, que da lugar al punto crítico a estudiar:

sol:solve([fx=0, fy=0],[x,y]);

punto_critico:[sol[1][1],sol[1][2]];

La función 'hessian' calcula de manera automática la matriz Hessiana de la función:

matriz_hessiana:hessian(f(x,y),[x,y]);

El determinante Hessiano (H) se calcula de forma inmediata a partir de ella:

H:determinant(matriz_hessiana);

La derivada parcial segunda, vale 2 como puede verse en la matriz Hessiana

fxx:diff(f(x,y),x,2);

is(fxx>0);

is(H>0);

Concluimos que el punto crítico identificado (1,-2) es un mínimo relativo. Lo representamos gráficamente:

wxdraw3d(explicit(f(x,y),x,0,2,y,-3,-1),
            point_type=filled_circle,
            point_size=2,
            color=red,            
            points([[1,-2,f(1,-2)]]));

kill(all);

rho1:1;

rho2(theta):=2*sin(2*theta);

Representacion gráfica del problema:

wxdraw2d(grid = true, nticks=1000, proportional_axes=xy,
             polar(rho2(theta), theta,0,2*%pi),
             color = "red",
             polar(1,theta,0,2*%pi),
             color=black,    
             parametric(0,t,t,-1.6,1.6),
             parametric(t,0,t,-1.6,1.6));

Buscamos los puntos de corte de la circunferencia con la rosa de cuatro hojas:

solve(rho2(theta)=1,theta);

theta1:%pi/12;

Por simetría, se deduce el segundo punto de corte:

theta2:%pi/2-theta1;

De modo que ya tenemos el intervalo de integración:

[theta1, theta2];

Por lo tanto, de acuerdo con la fórmula del área en polares, se construye la expresión del integrando:

integrando:(1/2)*(rho2(theta)^2-rho1^2);

Y conocido e intervalo de integración, se resuelve:

integrate(integrando, theta, theta1, theta2);

Expandimos el resultado, que tendrá unidades de área:

expand(%);

kill(all);

Se define la función subintegral:

f(x):=1/x^λ;

Se impone la condición a>0 del enunciado:

assume(a>0);

Ahora se impone la condición λ>1:

assume(λ>1);

facts();

I:integrate(f(x),x,a,inf);

is(I>0);

La integral da un valor real mayor que cero, luego es CONVERGENTE

Ahora se impone la condición λ<1. Para ello, primero es necesario anular el anteriro valor de λ:

forget(λ>1);

facts();

assume(λ<1);

facts();

integrate(f(x),x,a,inf);

En este caso, Maxima nos pide más detalles sobre el valor de lambda. En cualquier caso, la integrals será DIVERGENTE.

Lo mismo sucede cuando λ=1:

forget(λ<1);

λ:1;

integrate(f(x),x,a,inf);