# G1953 - Solución Primer Examen Parcial
28 Oct 2020

kill(all);

Se define w=x+yi:

w:x+y*%i;

Se calcula el cociente del enunciado, que llamaremos u. Expresamos el resultado en forma binómica con 'rectform':

u:w/(1+sqrt(3)*%i), rectform;

Se establecen las condiciones dadas por el enunciado a saber:

a) u es un número real, es decir, su parte imaginaria es nula:

ec1:imagpart(u)=0;

b) el módulo de w es la unidad:

ec2:x^2+y^2=1;

Se resuelve el sistema de dos ecuaciones (ec1 y ec2) y dos incógnitas (x,y):

sol:solve([ec1, ec2], [x,y]);

De aquí tenemos las dos soluciones de w:

sol[1];

sol[2];

rhs(sol[1][1]);

Se extraen las soluciones, w1 y w2:

w1:rhs(sol[1][1])+rhs(sol[1][2])*%i;

w2:rhs(sol[2][1])+rhs(sol[2][2])*%i;

Y finalmente se calcula el logaritmo de la raiz:

log(sqrt(w1)), rectform;

log(sqrt(w2)), rectform;

kill(all);

Para definir la serie, se define primeramente la sucesión que la origina:

a[n]:=((-1)^n*2^n)/(3^(n-2));

La serie de define entonces como:

S[k]:=sum(a[n],n,1,k);

### Criterio de Leibniz

Dado que se trata de una serie alternada, podemos plantearnos la aplicación del Teorema de Leibniz considerando la serie de la forma Σ(-1)^n*a[n]. Para ello, debemos comprobar (a) que el límite de la sucesión a[n] es cero y (b) que la sucesión a[n] es monótona decreciente 

define(b[n], abs(a[n]));

(a) El límite de b[n] verifica la primera condición:

limit(b[n],n,inf);

(b) Gráficamente, comprobamos que además a[n] es monótona estrictamente decreciente:

yvals:makelist(b[n],n,1,20)$

xvals:makelist(x,x,1,20)$

wxplot2d([discrete, xvals, yvals],[style,points]);

Formalmente:

is((b[n+1]/b[n])<1);

Por lo tanto, queda demostrado aplicando el Teorema de Leibniz que la serie converge. Comprobémoslo gráficamente. Para ello, calculamos las sumas parciales de los 20 primeros términos, y vemos que la serie converge al valor -0.1

yvalues:makelist(S[k], k, 1, 20)$

xvalues:makelist(x, x, 1, 20)$

wxplot2d([discrete, xvalues, yvalues], [style, linespoints]);

Con Maxima, calculamos fácilmente el valor de la suma infinita:

S[inf];

Nótese el uso de simpsum para representar de forma numérica dicha suma infinita:

S[inf], simpsum;

### Convergencia absoluta

kill(all);

a[n]:=((-1)^n*2^n)/(3^(n-2));

Apoyándonos en el Teorema del valor absoluto, podemos concluir que si la serie en valos absoluto es convergente, entonces la seré es convergente. En este caso tomamos la serie en valor absoluto:

b[n]:=abs(a[n]);

Se comprueba la condición  necesaria de convergencia

limit(b[n], n, inf);

Y se aplica alguno de los criterios para series de términos positivos. En este ejemplo, aplicamos el criterio de Cauchy, o criterio de la raiz:

L:limit(sqrt(b[n]),n,inf);

is(L<1);

La serie es absolutamente convergente, y por lo tanto es convergente. Lo mismo pudiera haberse determinado con otro criterio alternativo, por ejemplo el criterio de d'Alembert, o criterio del cociente:

L2:limit(b[n+1]/b[n], n, inf);

is(L2 < 1);

kill(all);

Se definen primeramente las funciones f(x), g(x) y h(x):

f(x):=(x+1)/(x^2-3*x-4);

g(x):=log(x);

h(x):=sqrt(x);

Denominamos ala función compuesta pedida ghf(x):

define(ghf(x), g(h(f(x))));

Debe asegurarse que todo lo que está dentro del logaritmo sea estrictamente mayor que cero. Nótese que la función no estrá definido para los puntos que anulan el denominador de f(x):

solve(x^2-3*x-4=0,x);

Gráficamente, podemos comprobar el dominio de dicha función, y de las funciones de partida:

wxplot2d([f(x), g(x), h(x), ghf(x)],[x,-10,50], [y,-5,5]);

Se comprueba que el dominio de definición de gofoh es (-4, +inf)

kill(all);

Se define la sucesión:

a[n]:=n^3*x^n/(4^n);

Esta es la serie de potencias resultante:

S[k]:=sum(a[n],n,1,k);

Criterio del cociente:

L:limit(a[n+1]/a[n],n,inf);

Si |x/4|<1 la serie será convergente, es decir |x|<4, y por lo tanto el radio de convergencia es R=4

Queda entonces por comprobar la convergencia/divergencia de la serie en los extremos del intervalo, cuando x=-4 y cuando x=4

x:-4;

a[n]:=n^3*x^n/(4^n);

limit(abs(a[n]), n, inf);

El límite no existe, y por lo tanto -4 no pertence al intervalo de convergencia

remvalue(a[n],x);

x:4;

a[n]:=n^3*x^n/(4^n);

limit(abs(a[n]), n, inf);

En este caso la serie diverge, y por lo tanto 4 no está dentro del intervalo de convergencia

Se concluye que el intervalo de convergencia de la serie es I=(-4,4)